Data Gridde Current control ve Renk değiştirme.

Public oForm

oForm = Createobject("myForm")

oForm.Show

 

Define Class myForm As Form

  DataSession = 2

  Height = 500

  Width = 800

 

  Add Object grd As Grid With Height=450,Width=800,ColumnCount = 5

  Add Object cmd As CommandButton With Caption="Dosya bagla", Top = 460

 

  Procedure Load

    Use (_samples+'data\customer')In 0

    Use (_samples+'data\Orders') In 0

  Endproc

 

  Procedure grd.Init

    With This.Columns(5)

      .Header1.Caption = ""

      .Newobject("btnDetay","detayGoster")

      .CurrentControl = "btnDetay"

      .btnDetay.Visible = .T.

      .Sparse =  .F.

    Endwith

    This.Columns(1).Header1.Caption = "Id"

    This.Columns(2).Header1.Caption = "Sirket"

    This.Columns(3).Header1.Caption = "Irtibat"

    This.Columns(4).Header1.Caption = "Unvan"

    This.RecordSource = ""

  Endproc

 

 

  Procedure cmd.Click

    Thisform.grd.RecordSource = ""

 

    Select Top 1 country,Rand() ;

      FROM (_samples+'data\customer') ;

      ORDER By 2 ;

      INTO Array aCountry

 

    Select cust_id,company,contact,Title ;

      FROM (_samples+'data\customer') ;

      WHERE country == aCountry ;

      INTO Cursor crsCustomer nofilter

    Thisform.grd.RecordSource = "crsCustomer"

    Thisform.grd.Autofit()

  Endproc

 

Enddefine

 

Define Class detayGoster As CommandButton

  Caption = "Detay"

  Procedure Click

    Select * From (_samples+'data\Orders') ;

      WHERE cust_id = crsCustomer.cust_id

  Endproc

Enddefine