Konu: Txt Dosyayı Xls Yapma
Oluşturduğumuz bir Txt dosyayı program içinden kodla Xls dosyaya dönüştürebilir miyiz?
- smentes
- Uzman Üye
- Offline
- cetinbasoz
- Uzman Üye
- Offline
Re: Txt Dosyayı Xls Yapma
Serafettin,
Text var text var. Delimited tarzi birsey oldugunu farzedersek birden fazla yolu var.
1) Eger ilk satirda kolon adlari var ise sadece uzantisini csv yap. Excel dogrudan acar.
2) Foxta yapisina uygun cursor yarat, append from ile al, xls olarak sakla.
3) ADO ile ac ADO ile gonder.
4) XML ise ya da hemen cevirebiliyorsan Excel'de OpenXML ile ac (otomasyon).
5) Excel otomasyon ile dogrudan excel'e actir, xls olarak saklat:
Visual Fox Pro
#define xlWorkbookNormal -4143
#DEFINE xlDelimited 1
#DEFINE xlFixedWidth 2
#DEFINE xlGeneralFormat 1
#DEFINE xlTextFormat 2
#DEFINE xlMDYFormat 3
#DEFINE xlDMYFormat 4
#DEFINE xlYMDFormat 5
#DEFINE xlMYDFormat 6
#DEFINE xlDYMFormat 7
#DEFINE xlYDMFormat 8
#DEFINE xlSkipColumn 9
#DEFINE xlEMDFormat 10
TEXT TO myVar noshow
0001,VFP7,01/01/2002,bu kolonu alma,30/01/2003,001,003
0002,VFP8,01/31/2003,skipme,29/02/2000,002
ENDTEXT
lcFileName = fullpath('ExcelOpenTextTest.txt')
STRTOFILE(m.myVar, m.lcFileName)
dimension arrFldInfo[7,2]
for ix=1 to 7
arrFldInfo[m.ix,1]=m.ix
endfor
arrFldInfo[1,2]=xlTextFormat
arrFldInfo[2,2]=xlTextFormat
arrFldInfo[3,2]=xlMDYFormat
arrFldInfo[4,2]=xlSkipColumn
arrFldInfo[5,2]=xlDMYFormat
arrFldInfo[6,2]=xlTextFormat
arrFldInfo[7,2]=xlGeneralFormat
oExcel = createobject('Excel.Application')
with oExcel
.Workbooks.OpenText(m.lcFileName,,,xlDelimited,,,,,.t.,,,, @arrFldInfo)
.ActiveWorkBook.SaveAs(ForceExt(m.lcFileName,'XLS'),xlWorkbookNormal)
.ActiveWorkBook.Saved = .T.
.visible = .T.
endwith
- smentes
- Uzman Üye
- Offline
Re: Txt Dosyayı Xls Yapma
Çetin bey,
1. Öneriniz tamam.
ancak 2. öneriniz daha kullanışlı. Teşekkürler