Sql Komut Hatası

sorun SQL syntaxta 255 karakter sınırına dayanmak sanırım asagidaki gibi halledebilirsin

TEXT TO m.lcSQL TEXTMERGE NOSHOW

    Insert Into CARHAR(;

    CARHARTAR,CARHARREFNO,CARHARTIPI,CARHARKAYONC,CARHARKAYNAK,;

    CARHARCARKOD,CARHARCARUNVAN,CARHARSIRANO,CARHARISTIPNO,;

    CARHARISTIPKOD,CARHAREVRAKNO,CARHARACIKLAMA,CARHARTUTAR);

    values('09.03.2012','78','2','2','8','01','ERCAN','1','8','FATURA','123','DENEME','998')

ENDTEXT

 

A1=SQLExec(m.lnHandle,m.lcSQL)

parametrik kısımlarıda tipine gore text..endext arasinda <<m.lnp1>> '<<m.lcp2>>' gibi kullanabilirsin bu sayede dis tarafa birsey almak zorunda kalmazsiniz.

ornek asagida path bilgisi text..endtext e parametrik gidiyor...

If _vfp.StartMode = 0

    m.gcPath = [d:\soykan\mysoftware\depomatik\z_atik_2012]

    Set Century On

    Set Date Dmy

Endif

 

TEXT TO m.lcSQL NOSHOW TEXTMERGE

    Select kod,tanim from;

    ADDBS('<<m.gcPath>>')+'depo';

    into curs CrsCboDepo nofilter

ENDTEXT

Execscript(m.lcSQL)

Bircok yerde SQL server'a asla boyle data gondermemelerini soyluyorum, burada da tekrarlamak boynumun borcu:) Buradaki degerlerin elle yazilmadigi asikar, bir yerden geliyor, bir yerden gelmesi demek SQL server'in "SQL Injection Attack" yani SQL kod ejekte eden saldirilara acik olmasi demek. Onlemek de son derece basit. Parametre kullanmak onluyor. Arti, parametre kullandiginizda ek bazi problemler onleniyor, nokta/virgul kullanilmis olmasi, string veri icinde tek/cift tirnak kullanilmasi, tarih formatlari, sayilar vs. Niye onlari SQL serverin anlayacagi stringe cevirmekle ugrasacaksin ki. Birak cevirimi suruculer yapsin. Mesela 9.3.2012'yi SQL server nasil anlayacak? Garanti mi onu 9 Mart 2012 diye anlamasi (degil, pekala 3 Eylul 2012 olarak da algilanabilir, sadece birisinin SQL serverdaki dateformat degerini degistirmesine bakar - isini saglama bagla, date/time degerlerini date/time gonder, stringe filan cevirme).

TEXT TO m.lcSQL TEXTMERGE NOSHOW

    Insert Into CARHAR(

    CARHARTAR,CARHARREFNO,CARHARTIPI,CARHARKAYONC,CARHARKAYNAK,

    CARHARCARKOD,CARHARCARUNVAN,CARHARSIRANO,CARHARISTIPNO,

    CARHARISTIPKOD,CARHAREVRAKNO,CARHARACIKLAMA,CARHARTUTAR)

    values

   (?m.CARHARTAR,?m.CARHARREFNO,?m.CARHARTIPI,?m.CARHARKAYONC,?m.CARHARKAYNAK,

    ?m.CARHARCARKOD,?m.CARHARCARUNVAN,?m.CARHARSIRANO,?m.CARHARISTIPNO,

    ?m.CARHARISTIPKOD,?m.CARHAREVRAKNO,?m.CARHARACIKLAMA,?m.CARHARTUTAR)

ENDTEXT

 

CARHARTAR = date(2012,3,9)

CARHARREFNO = 78

CARHARTIPI = 2

CARHARKAYONC = 2

CARHARKAYNAK = 8

CARHARCARKOD = '01'

CARHARCARUNVAN = 'ERCAN'

CARHARSIRANO = 1

CARHARISTIPNO = 8

CARHARISTIPKOD = 'FATURA' 

CARHAREVRAKNO = 123

CARHARACIKLAMA = 'DENEME'

CARHARTUTAR = 998

 

SQLExec( m.nHandle, m.lcSQL)

Baslamisken biriki not daha (ukalalik gibi oluyor:( ama bazen de hayat kurtarabilir):

-Stringlerde [ ] gerekmedikce kullanmayin (Gerci ayni sey text...endtext'de de oluyor, uyanik olun). Neden derseniz, #define degerlereriniz varsa bunlar [ ], text .. endtext kullanildiginda degerlediriliyor. Tek ve cift tirnakda degerlendirilimiyor. Ornek:

#define guzel cirkin

 

? 'VFP cok guzel bir dil'

? "VFP cok guzel bir dil"

? [VFP cok guzel bir dil]

Text to lcText noshow

VFP cok guzel bir dil

EndText

? m.lcText

Bunu bilerek yapiyorsaniz o zaman tamam. Dikkatli olun.

-Stringlerde 255 karakter siniri tirnak arasinda olan kisimlar icin gecerli. N tane 'tirnak icinde' olan kisimi birlestirip cok uzun (16 Mb dokumente edilen) string olabilir:

lcSQL = "select ..." +;

     " ... " +;

     " ..."

gibi. Her "..." bolum 255 karaktere kadar olabilir.

Diger ağdaki bilgisayarlarinda ana makinadaki sql servera baglanabilmesi icin SQL Server Native Client yuklemeleri gerekiyor

SQL Server 2008 Native Client x86 http://go.microsoft.com/fwlink/?LinkId= … lcid=0x409
SQL Server 2008 Native Client x64 http://go.microsoft.com/fwlink/?LinkId= … lcid=0x409

Client driverlarin olmasi yeterli degil. Server tarafinda ayarlamalar yapman da gerekiyor.  www.youtube.com adresine git. Yukaridaki arama yerine 'AccuSQL' yaz. 1 of 4 ... gibi 4 video goreceksin. 3 ve 4. videolar diger bilgisayarlardan baglanmayla ilgili.