Fareyi Hapsetmek

Declare Integer ClipCursor In WIN32API String @ lpRect

Declare Integer ClientToScreen In WIN32API Integer HWnd, String @ lpPoint

*DECLARE integer ScreenToClient IN WIN32API integer hWnd, string @ lpPoint

 

_Screen.AddObject("myShape","shape") && Just for showing where we lock the cursor

With _Screen.myShape

  .BackColor = 255

  .Left = 200

  .Top = 300

  .Width = 250

  .Height = 500

  .Visible = .T.

Endwith

 

LOCAL TopLeft,BottomRight

TopLeft     = CreatePoint(200,300)

BottomRight = CreatePoint(200+250,300+500)

ClientToScreen(_screen.HWnd, @TopLeft)   && convert shape's coordinates to desktop coordinates

ClientToScreen(_screen.HWnd, @BottomRight)

 

*lcClipTo = CreateRectangle(200,300,400,800) && direct screen coordinates

lcClipTo = m.TopLeft + m.BottomRight && clip area - rect structure

ClipCursor(@lcClipTo)

Wait Window "Any key to release"

ClipCursor(0)

_Screen.RemoveObject("myShape")

 

Function CreatePoint(m.tnX,m.tnY)

  Return ;

    BINTOC(m.tnX,"4RS")+;

    BINTOC(m.tnY,"4RS")

 

Function CreateRectangle(m.tnLeft,m.tnTop,m.tnRight,m.tnBottom)

  Return ;

    CreatePoint(m.tnLeft, m.tnTop)+;

    CreatePoint(m.tnRight,m.tnBottom)