1 Konuyu açan soykanozcelik

  • soykanozcelik
  • soykanozcelik
  • Uzman Üye
  • Offline
  • Yer: Tekirdağ
  • Kayıt Tarihi: 25.08.2006
  • İleti: 1,513

Konu: Sorgu sonucunu treeview ta gosterme

asagida final sorgusu olan cursorume ait data ornegi var bunu treeview olarak gostermek istiyorum,
+ ckodu-cadi
   + kod
         - detaylar
+ ckodu-cadi
   + kod
         - detaylar

seklinde olacak + tiklayinca alt satirda o koda ait cursor satirlari olacak
PS : ikinci asama olarak kod alanina ait gruplamada yapilabilir se daha detayli olur

boyle bir seyi nasil yapabilirim ?

Visual Fox Pro
CreateCursor__CRSUNION()

 

 

 Procedure CreateCursor__CRSUNION

 LOCAL lcData, lcTemp

 lcTemp = SYS(2015)+'.tmp'

 TEXT TO m.lcData noshow

 "A-015","DETAY ELK.- OKTAY DURGUT- VİZE",01.01.2008,1,"114","AÇILIŞ FİŞİ (BORÇ)","","","","",0.00,0.0000,2723.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,0.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",10.01.2008,10055,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","K-0152","TTR 3x1,5 KABLO",100.00,0.0000,93.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,93.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",10.01.2008,10055,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","S-0302","KÖHLER MONOFAZE DİJ. SAYAÇ",10.00,28.0000,289.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,289.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",18.01.2008,312,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","D-0035","NA-DE DAİRE DİAFON ŞUBESİ 050010",8.00,8.0000,66.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,66.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",18.01.2008,312,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","D-0036","NA-DE KAPICISIZ DİAFON SANTRALİ 050020",1.00,48.0000,48.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,48.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",18.01.2008,312,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","K-0052","-NYY 3x35/16 KABLO",40.00,17.0000,691.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,691.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",18.01.2008,312,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","P-0219","NA-DE 8 Lİ FOTOSELLİ HOP. ZİL PANOSU",1.00,40.0000,40.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,40.0000

"A-020","XX",14.02.2008,10248,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","K-0069","2x0,75 YASSI KORDON KABLO",200.00,0.0000,40.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,40.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",28.02.2008,10322,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","D-0205","TİJ DUY",100.00,0.0000,36.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,36.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",28.02.2008,10322,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","O-0083","SİEMENS 1P B 10A W OTOMAT",12.00,3.0000,39.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,39.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",28.02.2008,10322,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","O-0084","SİEMENS 1P B 16A W OTOMAT",12.00,3.0000,39.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,39.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",28.02.2008,10322,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","R-0132","SAYPORT 2P 40/30 A HK RÖLESİ",8.00,16.0000,133.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,133.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",28.02.2008,10322,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","S-0992","360º (10330) SENSÖRMATİK",10.00,24.0000,240.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,240.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",13.03.2008,10400,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","F-0015","Vİ-KO TOPRAKLI ERKEK FİŞ",50.00,1.0000,53.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,53.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",13.03.2008,10400,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","P-1400","LEYLAK 3 LÜ TOPR. KLEMENSLİ PRİZ",25.00,2.0000,57.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,57.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",19.04.2008,10644,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","K-0138","NYY 3x50/25 KABLO",30.00,26.0000,799.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,799.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",19.04.2008,10644,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","L-0100","GALVANİZ LEVHASI",1.00,29.0000,29.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,29.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",24.04.2008,10683,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","K-0152","TTR 3x1,5 KABLO",100.00,1.0000,103.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,103.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",24.04.2008,10683,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","P-0258","ÇP 416 PANO",1.00,352.0000,352.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,352.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",10.05.2008,3794,"046","TOPTAN SATIS FATURASI**","99","RDEPO","F-0015","Vİ-KO TOPRAKLI ERKEK FİŞ",50.00,0.0000,45.0000,0.00,0.00,0.00,0.0000,18.0,8.0000,0.00,0.0000,53.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",10.05.2008,3794,"046","TOPTAN SATIS FATURASI**","99","RDEPO","K-0069","2x0,75 YASSI KORDON KABLO",200.00,0.0000,36.0000,0.00,0.00,0.00,0.0000,18.0,6.0000,0.00,0.0000,42.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",10.05.2008,3794,"046","TOPTAN SATIS FATURASI**","99","RDEPO","K-0138","NYY 3x50/25 KABLO",20.00,23.0000,468.0000,0.00,0.00,0.00,0.0000,18.0,84.0000,0.00,0.0000,552.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",10.05.2008,3794,"046","TOPTAN SATIS FATURASI**","99","RDEPO","K-0152","TTR 3x1,5 KABLO",200.00,0.0000,170.0000,0.00,0.00,0.00,0.0000,18.0,30.0000,0.00,0.0000,200.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",10.05.2008,3794,"046","TOPTAN SATIS FATURASI**","99","RDEPO","P-1400","LEYLAK 3 LÜ TOPR. KLEMENSLİ PRİZ",25.00,1.0000,49.0000,0.00,0.00,0.00,0.0000,18.0,8.0000,0.00,0.0000,58.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",10.05.2008,3794,"046","TOPTAN SATIS FATURASI**","99","RDEPO","R-0132","SAYPORT 2P 40/30 A HK RÖLESİ",8.00,14.0000,113.0000,0.00,0.00,0.00,0.0000,18.0,20.0000,0.00,0.0000,134.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",10.05.2008,3794,"046","TOPTAN SATIS FATURASI**","99","RDEPO","S-0302","KÖHLER MONOFAZE DİJ. SAYAÇ",10.00,24.0000,245.0000,0.00,0.00,0.00,0.0000,18.0,44.0000,0.00,0.0000,289.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",10.05.2008,3794,"046","TOPTAN SATIS FATURASI**","99","RDEPO","S-0992","360º (10330) SENSÖRMATİK",5.00,20.0000,101.0000,0.00,0.00,0.00,0.0000,18.0,18.0000,0.00,0.0000,120.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",11.06.2008,4056,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","K--301","\NYA 2,5 KABLO",3000.00,0.0000,1020.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,1020.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",11.06.2008,4056,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","K-0001","-NYA 1,5 KABLO",2500.00,0.0000,525.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,525.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",11.06.2008,4056,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","K-0005","-NYA 10 KABLO",300.00,1.0000,405.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,405.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",11.06.2008,4056,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","K-0066","DT 8 DİAFON KABLO",100.00,0.0000,53.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,53.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",11.06.2008,4056,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","K-0346","EKO 12 Lİ W OT.KUTUSU S.A WK 0537,ÇET-SAN",12.00,4.0000,53.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,53.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",11.06.2008,4056,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","K-0617","ÇET-SAN 2 Lİ KRONE MODÜL KUTUSU",1.00,4.0000,4.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,4.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",11.06.2008,4056,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","S-0303","3x10(60)A TRİF. ELEKT. SAYAÇ",1.00,56.0000,56.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,56.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",11.06.2008,4056,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","Z-0205","1x40A B 3kA OTOMAT Vİ-KO",12.00,2.0000,30.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,30.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",03.07.2008,4700,"046","TOPTAN SATIS FATURASI**","99","RDEPO","K-0103","NYA 6 KABLO",300.00,0.0000,213.0000,0.00,0.00,0.00,0.0000,18.0,38.0000,0.00,0.0000,251.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",03.07.2008,4700,"046","TOPTAN SATIS FATURASI**","99","RDEPO","K-0104","NYA 10 KABLO",200.00,1.0000,252.0000,0.00,0.00,0.00,0.0000,18.0,45.0000,0.00,0.0000,297.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",03.07.2008,4700,"046","TOPTAN SATIS FATURASI**","99","RDEPO","K-0148","TTR 2x1,5 KABLO",100.00,0.0000,62.0000,0.00,0.00,0.00,0.0000,18.0,11.0000,0.00,0.0000,73.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",03.07.2008,4700,"046","TOPTAN SATIS FATURASI**","99","RDEPO","S-0302","KÖHLER MONOFAZE DİJ. SAYAÇ",5.00,24.0000,121.0000,0.00,0.00,0.00,0.0000,18.0,21.0000,0.00,0.0000,143.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",03.07.2008,11142,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","I-0006","İZOLE BANT",10.00,0.0000,2.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,2.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",03.07.2008,11142,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","K-0103","NYA 6 KABLO",300.00,0.0000,252.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,252.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",03.07.2008,11142,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","K-0104","NYA 10 KABLO",200.00,1.0000,298.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,298.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",03.07.2008,11142,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","K-0148","TTR 2x1,5 KABLO",100.00,0.0000,73.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,73.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",03.07.2008,11142,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","K-1056","ÇET-SAN 3 NO SIRA KLEMENS",50.00,1.0000,50.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,50.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",03.07.2008,11142,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","S-0302","KÖHLER MONOFAZE DİJ. SAYAÇ",5.00,28.0000,143.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,143.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",14.08.2008,11402,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","F-0015","Vİ-KO TOPRAKLI ERKEK FİŞ",50.00,1.0000,53.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,53.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",14.08.2008,11402,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","F-0071","EL-Bİ DELTA-GOLYAD ÜÇLÜ TOPR. FİŞ PRİZ",20.00,2.0000,52.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,52.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",14.08.2008,11402,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","I-0006","İZOLE BANT",50.00,0.0000,15.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,15.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",14.08.2008,11402,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","K--337","\TTR 2X1,5 KABLO",100.00,0.0000,67.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,67.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",14.08.2008,11402,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","K-0069","2x0,75 YASSI KORDON KABLO",200.00,0.0000,40.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,40.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",14.08.2008,11402,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","K-0152","TTR 3x1,5 KABLO",100.00,0.0000,94.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,94.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",14.08.2008,11402,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","K-0163","RG 6 U4 TV KABLO",100.00,0.0000,35.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,35.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",14.08.2008,11402,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","P-1416","LEYLAK 5 Lİ TOPR. KLE. PRİZ",10.00,3.0000,33.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,33.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",14.08.2008,11402,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","P-1424","LEYLAK 6 LI TOPR. KLEMENSLİ PRİZ",10.00,3.0000,39.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,39.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",14.08.2008,11402,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","P-1428","LEYLAK 6 LI ANAH. TOPR. KLE. PRİZ",5.00,6.0000,30.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,30.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",28.08.2008,11492,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","Z-0201","1x16A B 3kA OTOMAT Vİ-KO",24.00,2.0000,57.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,57.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",28.08.2008,11492,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","Z-0202","1x20A B 3kA OTOMAT Vİ-KO",24.00,2.0000,57.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,57.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",28.08.2008,11511,"009","SATIŞ İADE FATURASI-TOPTAN","03","UĞUR","K-0069","2x0,75 YASSI KORDON KABLO",200.00,0.0000,40.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,40.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",11.09.2008,6638,"046","TOPTAN SATIS FATURASI**","99","RDEPO","A-0237","SAYPORT 36 W FLORESAN",25.00,1.0000,27.0000,0.00,0.00,0.00,0.0000,18.0,4.0000,0.00,0.0000,32.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",11.09.2008,6638,"046","TOPTAN SATIS FATURASI**","99","RDEPO","R-0132","SAYPORT 2P 40/30 A HK RÖLESİ",5.00,16.0000,81.0000,0.00,0.00,0.00,0.0000,18.0,14.0000,0.00,0.0000,95.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",11.09.2008,6638,"046","TOPTAN SATIS FATURASI**","99","RDEPO","Z-0201","1x16A B 3kA OTOMAT Vİ-KO",60.00,2.0000,121.0000,0.00,0.00,0.00,0.0000,18.0,21.0000,0.00,0.0000,143.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",11.09.2008,6638,"046","TOPTAN SATIS FATURASI**","99","RDEPO","Z-0202","1x20A B 3kA OTOMAT Vİ-KO",60.00,2.0000,121.0000,0.00,0.00,0.00,0.0000,18.0,21.0000,0.00,0.0000,143.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",11.09.2008,11596,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","A-0237","SAYPORT 36 W FLORESAN",25.00,1.0000,32.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,32.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",11.09.2008,11596,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","R-0132","SAYPORT 2P 40/30 A HK RÖLESİ",5.00,19.0000,95.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,95.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",11.09.2008,11596,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","Z-0201","1x16A B 3kA OTOMAT Vİ-KO",60.00,2.0000,142.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,142.0000

"A-015","DETAY ELK.- OKTAY DURGUT- VİZE",11.09.2008,11596,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","Z-0202","1x20A B 3kA OTOMAT Vİ-KO",60.00,2.0000,142.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,142.0000

"A-020","XX",18.09.2008,6841,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","K-1056","ÇET-SAN 3 NO SIRA KLEMENS",50.00,1.0000,53.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,53.0000

"A-020","XX",18.09.2008,6841,"002","SATIŞ FATURASI-TOPTAN","03","UĞUR","R-0160","ESEM 2P 40/30 A HK RÖLESİ",12.00,20.0000,249.0000,0.00,0.00,0.00,0.0000,0.00,0.0000,0.00,0.0000,249.0000

 

 ENDTEXT

 

 STRTOFILE(m.lcData,m.lcTemp)

 

 create CURSOR _CRSUNION ;

 ( ;

  CKODU C(16,0)  NOT  NULL  ;

  ,CADI C(60,0)  NOT  NULL  ;

  ,TARIH D(8,0)  NOT  NULL  ;

  ,ISLEMNO I(4,0)  NOT  NULL  ;

  ,KOD C(3,0)  NOT  NULL  ;

  ,TANIM C(50,0)  NOT  NULL  ;

  ,DEPOKODU C(10,0)  NOT  NULL  ;

  ,DEPOADI C(10,0)  NOT  NULL  ;

  ,SKODU C(16,0)  NOT  NULL  ;

  ,SADI C(50,0)  NOT  NULL  ;

  ,MIKTAR N(10,2)  NULL  ;

  ,FIYAT N(10,4)  NULL  ;

  ,TUTAR N(15,4)  NULL  ;

  ,ISKONTO N(15,2)  NULL  ;

  ,ISKONTO2 N(15,2)  NULL  ;

  ,ISKONTO3 N(15,2)  NULL  ;

  ,ISKTUTAR N(15,4)  NULL  ;

  ,KDV N(4,2)  NULL  ;

  ,KDVTUT N(15,4)  NULL  ;

  ,OTV N(4,2)  NULL  ;

  ,OTVTUT N(15,4)  NULL  ;

  ,GTOPLAM N(15,4)  NULL  ;

  )

 

 APPEND FROM (m.lcTemp) TYPE delimited

 ERASE (m.lcTemp)

 endproc

 endproc
https://www.twitter.com/soykanozcelik https://www.t.me/soykanozcelik https://soykanozcelik.wordpress.com

soykanozcelik's Website

2 Cevaplayan cetinbasoz

  • cetinbasoz
  • cetinbasoz
  • Uzman Üye
  • Offline
  • Kayıt Tarihi: 07.10.2006
  • İleti: 3,162

Re: Sorgu sonucunu treeview ta gosterme

Eski mesajlarda hierarchical flex grid vardi. Bence bu aslinda onun isi. TV ile yapmak istersen:

Visual Fox Pro
Public oForm

oForm = Createobject('myForm')

oForm.Show()

 

Define Class myForm As Form

  Height=600

  Width=800

  Add Object Tree As OleControl With ;

    Name = 'Tree',OleClass='MSComCtlLib.TreeCtrl'

 

  Procedure Init

    #Define tvwFirst    0

    #Define tvwLast    1

    #Define tvwNext    2

    #Define tvwPrevious    3

    #Define tvwChild    4

 

    With This.Tree

      .linestyle = 1

      .indentation = 5

      .Width = 800

      .Height = 600

 

      Select _CRSUNION

      Copy To myRows.txt Delimited With "" With Character "|"

      Local Array aRows[1]

      Alines(aRows, Filetostr('myRows.txt'))

      Erase ('myRows.txt')

 

      Scan

        p0key1 = 'ckod'+Rtrim(CKODU)

        p0key2 = 'kod'+Rtrim(KOD)

        p1key = Trim('ck'+Sys(2007,CKODU+KOD,1,1))

 

        If Type('.Nodes(m.p0key1)') = 'U'

          .Nodes.Add(,tvwFirst,m.p0key1,Rtrim(CKODU)+' - '+Rtrim(CADI))

        Endif

        If Type('.Nodes(m.p0key2)') = 'U'

          .Nodes.Add(,tvwFirst,m.p0key2,Trim(KOD))

        Endif

        If Type('.Nodes(m.p1key)') = 'U'

          .Nodes.Add(m.p0key1,tvwChild,m.p1key,Trim(KOD))

        Endif

 

        Key1 = Textmerge('cRow_<<RECNO()>>')

        Key2 = Textmerge('kRow_<<RECNO()>>')

 

        .Nodes.Add(m.p0key2,tvwChild,m.Key1,aRows[RECNO()])

        .Nodes.Add(m.p1key,tvwChild,m.Key2,aRows[RECNO()])

      Endscan

 

    Endwith

  Endproc

Enddefine

cetinbasoz's Website

3 Cevaplayan soykanozcelik

  • soykanozcelik
  • soykanozcelik
  • Uzman Üye
  • Offline
  • Yer: Tekirdağ
  • Kayıt Tarihi: 25.08.2006
  • İleti: 1,513

Re: Sorgu sonucunu treeview ta gosterme

tesekkurler smile
Hflex ile bir ornek istesem cokmu sey mi istemis olurum smile

PS : evet SampleDataAsText cok isime yariyor hatta program defaultu icin kullandigim yerle var
birim setleri , sabit tanimlar gibi smile

https://www.twitter.com/soykanozcelik https://www.t.me/soykanozcelik https://soykanozcelik.wordpress.com

soykanozcelik's Website

4 Cevaplayan cetinbasoz

  • cetinbasoz
  • cetinbasoz
  • Uzman Üye
  • Offline
  • Kayıt Tarihi: 07.10.2006
  • İleti: 3,162

Re: Sorgu sonucunu treeview ta gosterme

KDV yi I(4,0) olarak duzelt:

Visual Fox Pro
CreateCursor__CRSUNION()

ToHFlex()

Visual Fox Pro
Procedure ToHFlex

  Local strCn,strShp, testDataLoc

 

  lcTemp = Forcepath(Sys(2015)+'.dbf',Sys(2023))

 

  Select _CRSUNION

  Copy To (m.lcTemp)

 

  strCn =    'Provider=MSDataShape;Persist Security Info=False;'+;

    'Data Source='+Sys(2023)+';Data Provider=VFPOLEDB'

 

  TEXT TO m.strShp TEXTMERGE noshow

SHAPE { select distinct cKodu,cAdi from ('<<m.lcTemp>>') }

  APPEND ( (SHAPE { select distinct cKodu,cAdi, kod, tanim, cKodu+kod as cKod2Kod from ('<<m.lcTemp>>') }

    APPEND ( {select *, cKodu+kod as cKod2Kod

                from ('<<m.lcTemp>>')} RELATE cKod2Kod TO cKod2Kod))

  RELATE ckodu TO ckodu )

  ENDTEXT

  ToADORs(m.strCn,m.strShp)

  Erase (m.lcTemp)

Endproc

 

Function ToADORs(tcConn, tcSQL)

  Local oRecordset As "adodb.recordset",oConnection As "adodb.connection"

  oRecordset = Createobject("adodb.recordset")

  oConnection = Createobject("adodb.connection")

 

  With oConnection

    .ConnectionString = m.tcConn

    .Open

  Endwith

 

  With oRecordset

    .ActiveConnection = oConnection

    .Source = m.tcSQL

    .Open

  Endwith

 

  Public oForm

  oForm = Createobject('myForm', oRecordset)

  oForm.Show(1)

Endfunc

 

 

Define Class myform As Form

  Height = 450

  Width = 750

 

  Add Object hflex As OleControl With ;

    Top = 10, Left = 10, Height = 430, Width = 730, Name = "Hflex", ;

    OleClass = 'MSHierarchicalFlexGridLib.MSHFlexGrid'

 

  Procedure Init

    Lparameters toRecordset

    With This.hflex

      .FixedCols = 0

      .Datasource = toRecordset

      .AllowUSerResizing = 3

      .CollapseAll

    Endwith

  Endproc

Enddefine

cetinbasoz's Website

5 Cevaplayan soykanozcelik

  • soykanozcelik
  • soykanozcelik
  • Uzman Üye
  • Offline
  • Yer: Tekirdağ
  • Kayıt Tarihi: 25.08.2006
  • İleti: 1,513

Re: Sorgu sonucunu treeview ta gosterme

tesekkur gayet guzel calisiyor smile
ancak 130.000 kayitli gercek sorgu sonucunda Treeview ve Hflex te takildi sad

https://www.twitter.com/soykanozcelik https://www.t.me/soykanozcelik https://soykanozcelik.wordpress.com

soykanozcelik's Website

6 Cevaplayan metin

  • metin
  • metin
  • Uzman Üye
  • Offline
  • Yer: istanbul
  • Kayıt Tarihi: 16.10.2006
  • İleti: 1,460

Re: Sorgu sonucunu treeview ta gosterme

cetinbasoz yazdı:

KDV yi I(4,0) olarak duzelt:

...


eskiden %12,5 kdv vardı.  wink

bizim devletin sağı solu belli olmaz.

bence en iyisi n(5,2)...

Haksızlıklar karşısında susanlar, dilsiz şeytanlardır!
www.metinemre.com

metin's Website

7 Cevaplayan metin

  • metin
  • metin
  • Uzman Üye
  • Offline
  • Yer: istanbul
  • Kayıt Tarihi: 16.10.2006
  • İleti: 1,460

Re: Sorgu sonucunu treeview ta gosterme

bende .open satırında hata verdi.
...
With oRecordset
    .ActiveConnection = oConnection
    .Source = m.tcSQL
    .Open
  Endwith
...

Hata mesajı:
OLE IDispatch exception code 0 from Microsoft Cursor Engine: Veri sağlayıcısı veya diğer bir hizmet E_FAIL durumu verdi...

Haksızlıklar karşısında susanlar, dilsiz şeytanlardır!
www.metinemre.com

metin's Website

8 Cevaplayan metin

  • metin
  • metin
  • Uzman Üye
  • Offline
  • Yer: istanbul
  • Kayıt Tarihi: 16.10.2006
  • İleti: 1,460

Re: Sorgu sonucunu treeview ta gosterme

soykanozcelik yazdı:

tesekkur gayet guzel calisiyor smile
ancak 130.000 kayitli gercek sorgu sonucunda Treeview ve Hflex te takildi sad


of ne yaptın? kayıtları parça parça getirmelisin. 130.000 kayıtlı cursor çok fazla.

Haksızlıklar karşısında susanlar, dilsiz şeytanlardır!
www.metinemre.com

metin's Website

9 Cevaplayan soykanozcelik

  • soykanozcelik
  • soykanozcelik
  • Uzman Üye
  • Offline
  • Yer: Tekirdağ
  • Kayıt Tarihi: 25.08.2006
  • İleti: 1,513

Re: Sorgu sonucunu treeview ta gosterme

evet ön filtreleme gerekecek yani bu tarih aralığı olabilir,kod araligi,grup kodu vs ozaman
olusan kayit sayisi daha az olacak treeview limitinin 32.000 gibi bir rakam oldugunu okudum hatadan sonra arastirinca

http://www.google.com.tr/search?q=treev … =firefox-a

ordan bir alinti

One source put the limit of nodes in a Treeview at 32,000. If this is in fact the case, I assume that dynamically adding nodes as the user expands a parent node and removing those (added) children once the user collapses that parent can still make the control practical for most uses. Of course this would also be dependent on the user’s collapsing some of those expanded nodes from time to time.

kayitlari parca parca getir derken o kısmı tam anlayamadim ?

https://www.twitter.com/soykanozcelik https://www.t.me/soykanozcelik https://soykanozcelik.wordpress.com

soykanozcelik's Website

10 Cevaplayan cetinbasoz

  • cetinbasoz
  • cetinbasoz
  • Uzman Üye
  • Offline
  • Kayıt Tarihi: 07.10.2006
  • İleti: 3,162

Re: Sorgu sonucunu treeview ta gosterme

Visual Fox Pro
Procedure ToSideBySide

  Public oForm

  oForm = Createobject('mySbS')

  oForm.Show(1)

Endproc

 

Define Class mySbS As Form

  Height=600

  Width=800

  Add Object grd1 As Grid With Top=  0,Left=  0,Height=200,Width=400,Anchor=131,;

    RecordSource = 't1',AllowCellSelection=.F.

  Add Object grd2 As Grid With Top=  0,Left=400,Height=200,Width=400,Anchor= 41,;

    RecordSource = 't2',AllowCellSelection=.F.

  Add Object grd3 As Grid With Top=200,Left=  0,Height=400,Width=800,Anchor= 15,;

    RecordSource = 't3',AllowCellSelection=.F.

 

  Procedure Load

    Select Distinct CKODU,CADI From _CRSUNION Into Cursor t1

    Select Distinct KOD,TANIM,CKODU,CADI From _CRSUNION Into Cursor t2 nofilter

    Index On CKODU Tag CKODU

    Select * From _CRSUNION Into Cursor t3 nofilter

    Index On CKODU+KOD Tag Main

    Set Relation To CKODU+KOD Into t3 In t2

    Set Relation To CKODU Into t2 In t1

  Endproc

 

  Procedure grd1.AfterRowColChange

    Lparameters nColIndex

    If This.RowColChange%2=1

      Thisform.Refresh

    Endif

  Endproc

 

  Procedure grd2.AfterRowColChange

    Lparameters nColIndex

    If This.RowColChange%2=1

      This.Parent.grd3.Refresh

    Endif

  Endproc

Enddefine

Metin,
Sadece kdv n(4,2) satirini i(4,0) yap calisiyor.

cetinbasoz's Website

11 Cevaplayan metin

  • metin
  • metin
  • Uzman Üye
  • Offline
  • Yer: istanbul
  • Kayıt Tarihi: 16.10.2006
  • İleti: 1,460

Re: Sorgu sonucunu treeview ta gosterme

pardon ben kdv'yi yanlış tanımlamış diye öyle demek istediğini sandım. çünkü 4,2 olunca çift haneli kdv giremez... oldu. teşekkürler...

Haksızlıklar karşısında susanlar, dilsiz şeytanlardır!
www.metinemre.com

metin's Website

12 Cevaplayan metin

  • metin
  • metin
  • Uzman Üye
  • Offline
  • Yer: istanbul
  • Kayıt Tarihi: 16.10.2006
  • İleti: 1,460

Re: Sorgu sonucunu treeview ta gosterme

güzel bişeymiş bu. sevdim... peki theme desteği yok mu?

Haksızlıklar karşısında susanlar, dilsiz şeytanlardır!
www.metinemre.com

metin's Website

13 Cevaplayan cetinbasoz

  • cetinbasoz
  • cetinbasoz
  • Uzman Üye
  • Offline
  • Kayıt Tarihi: 07.10.2006
  • İleti: 3,162

Re: Sorgu sonucunu treeview ta gosterme

Sanmam oldugunu o cok eski, theme diye birsey yoktu ortada. Ancak her band (hiyerarsinin her seviyesi bir band) ayri ayri renklendirilebiliyor, hatta hucre bazinda renk verebiliyorsun, hucreye resim koyabiliyorsun, benzer komsu hucreleri merge eebiliyorsun, dikdortgen bir alani secebiliyorsun vs. (ama her property her zaman calismiyor, sartlari var).

cetinbasoz's Website

14 Cevaplayan metin

  • metin
  • metin
  • Uzman Üye
  • Offline
  • Yer: istanbul
  • Kayıt Tarihi: 16.10.2006
  • İleti: 1,460

Re: Sorgu sonucunu treeview ta gosterme

eee yok mudur bunun yenisi?

Haksızlıklar karşısında susanlar, dilsiz şeytanlardır!
www.metinemre.com

metin's Website