Grafikte sütun max değerini sabitleme

*** set the LOCALEID to English

nlLocaleId=Sys(3004)        && Save local id

=Sys(3006,1033)                && We will be sending instructions in English

 

* Part of xlChartType constants

#Define xl3DArea                     -4098

#Define xl3DColumn                    -4100

#Define xl3DLine                    -4101

#Define xl3DPie                        -4102

#Define xlArea                        1

#Define xlBar                       2

#Define xlColumn                    3

#Define xlLine                        4

#Define xlPie                        5

 

*** Constant Group: XlAxisType

#Define xlCategory                                        1

#Define xlSeriesAxis                                      3

#Define xlValue                                           2

*** Constant Group: XlRowCol

#Define xlColumns                                         2

#Define xlRows                                            1

 

 

Create Cursor testgen (graph1 g, graph2 g, graph3 g)

Append Blank

Append General graph1 Class msgraph.Chart Data GetDataSet(200)

Append General graph2 Class msgraph.Chart Data GetDataSet(500)

Append General graph3 Class msgraph.Chart Data GetDataSet(300)

 

Public oForm

oForm = Createobject("Form")

With oForm

  .Height = 400

  .Width = 920

  .Show

  .AddObject('myGraph1','OleBoundControl')

  .AddObject('myGraph2','OleBoundControl')

  .AddObject('myGraph3','OleBoundControl')

 

  With .myGraph1

    .Height = oForm.Height - 20

    .Width = 300

    .Left = 0

    .Top = 0

    .ControlSource = "testgen.graph1"

    .Object.Application.plotby = xlColumns

    .HasLegend = .F.

    .Axes(xlValue).MaximumScale = 500

    .Visible=.T.

  Endwith

  With .myGraph2

    .Height = oForm.Height - 20

    .Width = 300

    .Left = 310

    .Top = 0

    .ControlSource = "testgen.graph2"

    .Object.Application.plotby = xlColumns

    .HasLegend = .F.

    .Axes(xlValue).MaximumScale = 500

    .Visible=.T.

  Endwith

  With .myGraph3

    .Height = oForm.Height - 20

    .Width = 300

    .Left = 620

    .Top = 0

    .ControlSource = "testgen.graph3"

    .Object.Application.plotby = xlColumns

    .HasLegend = .F.

    .Axes(xlValue).MaximumScale = 500

    .Visible=.T.

  Endwith

Endwith

**** Set the LocaleId to the previous value

=Sys(3006,Val(nlLocaleId))

 

Procedure GetDataSet(tnMax)

  Local lcTemp, cData, lnSelect

  lnSelect = Select()

  Rand(-1)

  Create Cursor DataSheet (Kategori c(10), ColA i, colB i, colC i)

  For ix = 1 To 5

    Insert Into DataSheet Values ;

      ('Row #'+Padl(m.ix,2,'0'),Rand()*m.tnMax, Rand()*m.tnMax, Rand()*m.tnMax)

  Endfor

  lcTemp = Forcepath(Sys(2015)+'.tmp',Sys(2023))

 

  Copy To (m.lcTemp) Type Csv

  cData = Chrtran(Filetostr(m.lcTemp),',',Chr(9))

  Erase (m.lcTemp)

  Use In 'DataSheet'

  Select (m.lnSelect)

  Return m.cData

endproc

WITH Thisform.OleBoundControl01 AS "MSGraph.Chart"

    .ControlSource = "anadata.fiyat"

    .HasLegend = .t.

    .autoformat(-4100,1)

    .Axes(2).MinimumScale = MINS   &&minimum değerin 

    .Axes(2).MaximumScale = MAXS  &&maximum değerin

ENDWITH

.....

THISform.LockScreen = .T.

Thisform.OleBoundControl01.ControlSource=""

SELECT anadata

APPEND GENERAL fiyat CLASS MSGraph.Chart DATA lcData

WITH Thisform.OleBoundControl01 AS "MSGraph.Chart"

    .ControlSource = "anadata.fiyat"

    .HasLegend = .t.

    .autoformat(-4100,1)

    .Axes(2).MinimumScale = MINS   &&minimum değerin 

    .Axes(2).MaximumScale = MAXS  &&maximum değerin

ENDWITH

THISform.LockScreen = .F.