Excele Aktarırken Tarih Formatı

p1 = ALLTRIM(thisform.c1.value)+'%'

p2 = ALLTRIM(thisform.c2.value)+'%'

t1 = Thisform.t1.Value

t2 = Thisform.t2.Value

Select * From Ornek ;

  WHERE ;

  PID >= 1 And ;

  olay='falan' And ;

  isim Like ?m.p1 And ;

  il Like ?m.p2 And ;

  tarih Between ?m.t1 And ?m.t2 ;

  Into Cursor crsExcel nofilter

 

Local oExcel

oExcel = Createobject("Excel.Application")

With oExcel

  .DisplayAlerts = .F.

  .Workbooks.Add

  .Visible = .T.

  With .ActiveWorkBook

    VFP2Excel('crsExcel', .WorkSheets(1).Range("A1"), "" ) && sheet1, A1, baslik field adlari

    .WorkSheets(1).Activate

  Endwith

Endwith

 

* Warning:

* Copying to a free table (might be dbc based)

* temporarily and using field names as headers

* if not passed.

* This might lead to problems like:

* Truncated fieldnames of 2 columns collide and copy to errors

* Field names might be cryptic for the enduser

Function VFP2Excel

  Lparameters tcCursorName, toRange, tcHeaders

  tcCursorName = Iif(Empty(m.tcCursorName),Alias(),m.tcCursorName)

  Local loConn As AdoDB.Connection, loRS As AdoDB.Recordset,;

    lcTemp, oExcel,ix

 

  lcTemp = Forcepath(Sys(2015)+'.dbf',Sys(2023))

  Select (m.tcCursorName)

  Copy To (m.lcTemp)

  loConn = Createobject("Adodb.connection")

  loConn.ConnectionString = "Provider=VFPOLEDB;Data Source="+Sys(2023)

  loConn.Open()

  loRS = loConn.Execute("select * from "+m.lcTemp)

 

  * Use first row for headers

  Local Array aHeader[1]

 

  toRange.Offset(1,0).CopyFromRecordSet( loRS )  && Copy data starting from headerrow + 1

  For ix=1 To Iif( !Empty(m.tcHeaders), ;

      ALINES(aHeader, m.tcHeaders,1,','), ;

      loRS.Fields.Count )

    toRange.Offset(0,m.ix-1).Value = ;

      Iif( !Empty(m.tcHeaders), ;

      aHeader[m.ix], ;

      Proper(loRS.Fields(m.ix-1).Name) )

    toRange.Offset(0,m.ix-1).Font.Bold = .T.

  Endfor

 

  loRS.Close

  loConn.Close

  Erase (m.lcTemp)

Endfunc

toRange.Offset(1,0).CopyFromRecordSet( loRS )  && Copy data starting from headerrow + 1

Field(Ascan(xxx,Proper(loRS.Fields(m.ix-1).Name,1,Alen(xxx,1),1,8))) )