Browse komutunda renkli gösterme

ThisForm.grdSonuc.SetAll("DynamicBackColor", "IIf(dTarih > Date(), RGB(255,0,0), IIf(dTarih < Date(), RGB(0,0,255), RGB(0,255,0)))", "Column")

Public goForm As Form

 

Create Cursor Deneme (cAd C(20), cSoyad C(30), dKayitTarihi D)

Insert Into Deneme Values("Tarkan", "Haser", Date(2000, 5, 5))

Insert Into Deneme Values("Özgür", "Yıldırım", Date(2001, 4, 14))

Insert Into Deneme Values("Mutlu", "Önder", Date(2003, 6, 11))

Insert Into Deneme Values("Mustafa", "Ceyhan", Date(2005, 11, 3))

Locate

 

m.goForm = CreateObject("TabloGoster", "Deneme", "Üyeler", "IIf(dKayitTarihi < Date(2003,1,1), RGB(255,0,0), RGB(0,0,255))")

m.goForm.Show(1)

 

DEFINE CLASS TabloGoster As Form

 

    Height = 200

    Width = 320

    DoCreate = .T.

    Name = "frmTabloGoster"

 

 

    ADD OBJECT grdtablogoster AS Grid WITH ;

        Anchor = 15, ;

        Name = "grdTabloGoster"

 

 

    PROCEDURE Init

        LParameters tcAlias As String, tcBaslik As String, tcDynamicBackColor As String

        If Empty(m.tcAlias) Or Type("tcAlias") <> "C" Or !Used(m.tcAlias)

            Return .F.

        EndIf

        With ThisForm

            If Empty(m.tcBaslik)

                .Caption = m.tcAlias

            Else

                .Caption = m.tcBaslik

            EndIf

            Local lnI As Integer, loObje As Object

 

            With .grdTabloGoster

                .ColumnCount = FCount(m.tcAlias)

                .RecordSource = m.tcAlias

                For m.lnI = 1 To .ColumnCount

                    For Each m.loObje In .Columns(m.lnI).Objects

                        If m.loObje.BaseClass = "Header"

                            m.loObje.Caption = Field(m.lnI, m.tcAlias)

                        EndIf

                    EndFor

                EndFor

                If !Empty(m.tcDynamicBackColor) And Type("m.tcDynamicBackColor") = "C"

                    .SetAll("DynamicBackColor", m.tcDynamicBackColor, "Column")

                EndIf

            EndWith

        EndWith

    ENDPROC

ENDDEFINE

Select Date()-5+Int(Rand()*7) As tarih,* ;

  FROM (_samples + 'data\orders') ;

  INTO Cursor ornek ;

  nofilter

Local lSet

Browse For tarih <= Date()+1 ;

  TITLE 'Renkli Browse' ;

  WHEN SetGrid(@lSet) ;

  NAME oBrowse

 

Function SetGrid(tlSet)

  If !m.tlSet

    With oBrowse

      .DeleteMark = .F.

      .RecordMark = .F.

      .GridLines = 2

      .ScrollBars = 2

      .AllowRowSizing = .F.

      .Height = 400

      .Width = 600

      .SetAll("DynamicForeColor", 'ICASE('+;

        'Tarih = date()+1, 0,'+;

        '0xFFFFFF)')

      .SetAll("DynamicBackColor", 'ICASE('+;

        'Tarih = date()+1, 0x00FF00,'+;

        'Tarih = date(), 0xFF0000, '+;

        '0x0000FF)')

    Endwith

    tlSet=.T.

  Endif

endfunc