indentation

#Define tvwFirst    0

#Define tvwLast    1

#Define tvwNext    2

#Define tvwPrevious    3

#Define tvwChild    4

 

Public oForm

oForm = Createobject('myForm')

oForm.Show()

 

Define Class myForm As Form

  DataSession=2

  Height = 600

  Width = 800

 

  Add Object Tree As OleControl With ;

    Name = 'Tree',OleClass='MSComCtlLib.TreeCtrl', ;

    Height=600,Width=800

 

  Procedure Load

    Select 1 As Level,Sys(2015) As nodeID, '' As parentID,Company As NodeText, cust_id ;

      From (_samples+'data\customer') Into Cursor level0 nofilter

    Select 2 As Level,Sys(2015) As nodeID, level0.nodeID As parentID, order_ID As NodeText, order_ID ;

      FROM (_samples+'data\orders') ;

      INNER Join level0 On orders.cust_id = level0.cust_id ;

      INTO Cursor level1 nofilter

    Select 3 As Level, Sys(2015) As nodeID, level1.nodeID As parentID, products.prod_name - ('['+Ltrim(Str(quantity))+']')  As NodeText ;

      FROM (_samples+'data\orditems') ;

      INNER Join (_samples+'data\products') On orditems.product_id = products.product_id ;

      INNER Join level1 On orditems.order_ID = level1.order_ID ;

      INTO Cursor level2 nofilter

 

    Select Level,nodeID,parentID,NodeText From level0 ;

      UNION ;

      SELECT Level,nodeID,parentID,NodeText From level1 ;

      UNION ;

      SELECT Level,nodeID,parentID,NodeText From level2 ;

      ORDER By Level Into Cursor treeData

  Endproc

 

  Procedure Init

    With This.Tree

      .linestyle = 1

      .Font.Name = 'Times New Roman'

      .Font.Size = 10

      .indentation = 5

 

      Select treeData

      Scan

        If Empty(parentID)

          .Nodes.Add(,tvwFirst,nodeID,NodeText)

        Else

          .Nodes.Add(parentID,tvwChild,nodeID,NodeText)

        Endif

      Endscan

 

    Endwith

  Endproc

Enddefine