combobox i bir tablodan doldurup belirli bir ID yi secili gostermek

Public oForm

oForm = Createobject('comboOrnek')

oForm.Show

 

Define Class ComboOrnek As Form

  DataSession = 2

  Add Object cmbOrnek As ComboBox With Top = 10,Left = 10, Width = 200

  Add Object btnGoster As CommandButton With Top = 10,Left = 210, Caption = 'Goster'

  Add Object txt1 As TextBox With Top = 50,Left = 10, Width = 200

  Add Object txt2 As TextBox With Top = 80,Left = 10, Width = 200

  Add Object txt3 As TextBox With Top = 110,Left = 10, Width = 200

  Add Object txt4 As TextBox With Top = 140,Left = 10, Width = 200

  Add Object txt5 As TextBox With Top = 170,Left = 10, Width = 200

  Add Object txt6 As TextBox With Top = 200,Left = 10, Width = 200

  Add Object txt7 As TextBox With Top = 200,Left = 210, Width = 20

  Add Object txt8 As TextBox With Top = 230,Left = 10, Width = 200

  Add Object txt9 As TextBox With Top = 230,Left = 210, Width = 20

 

  Procedure cmbOrnek.Init

    With This

      .RowSourceType = 3

      TEXT TO .RowSource NOSHOW PRETEXT 15

select

    first_Name-(' '+Last_Name-(":["+order_id+"]")) as empOrder,

    employee.emp_id as myId,

    orders.*

 from (_samples+'data\employee') employee

   INNER JOIN (_samples+'data\orders') orders

     ON employee.emp_id == orders.emp_id

 ORDER BY 1

 into cursor xx nofilter

      ENDTEXT

      .ColumnCount = 1

      .BoundColumn = 2

    Endwith

  Endproc

 

  Procedure cmbOrnek.InteractiveChange

    With Thisform

      .txt1.Value = This.Text

      .txt2.Value = This.Value

      .txt3.Value = This.DisplayValue

      .txt4.Value = This.ListIndex

      .txt5.Value = xx.myId

      .txt6.Value = xx.order_date

      .txt7.Value = Type('xx.order_date') && data tipi date

      Local Array aFieldList[1]

      Local lnOrderDateCol,luValue

      Afields(aFieldList,'xx')

      lnOrderDateCol = Ascan(aFieldList,'order_date',1,-1,1,1+2+4+8)

      luValue = This.List(This.ListIndex, m.lnOrderDateCol)

      .txt8.Value = m.luValue

      .txt9.Value = Type('m.luValue') && data tipi char

    Endwith

  Endproc

 

  Procedure btnGoster.Click

    Cursortoxml('xx','lcXML',1,2,1)

    Messagebox("Secilen kayit:"+Chr(13)+m.lcXML)

  Endproc

Enddefine