Grid olan bir formda New, Save, Revert tuşu

Create Database SampleDb

Local lcProc

TEXT to m.lcProc noshow

Procedure UniqueID

Local pGUID,rGUID

Declare Integer UuidCreate In 'RPCRT4.dll' String @pguid

Declare Integer StringFromGUID2 In 'Ole32.dll' ;

  string rguid, String @lpsz, Integer cchMax

 

pGUID=Replicate(Chr(0),16)

rGUID=Replicate(Chr(0),80)

 

UuidCreate(@pGUID)

StringFromGUID2(pGUID,@rGUID,40)

RETURN Strconv(Left(rGUID,76),6)

ENDTEXT

Strtofile(m.lcProc, 'tempProcs.prg')

Append Procedures From ('tempProcs.prg')

Erase ('tempProcs.prg')

 

Create Table malzemeAdi (malzemeKod c(38) Default UniqueID(), malzemeAdi c(50))

Alter Table 'MalzemeAdi' Add Primary Key malzemeKod Tag malzemeKod

Local ix

For ix=1 To 100

  Insert Into malzemeAdi (malzemeAdi) Values ('Malzeme #'+Padl(m.ix,3,'0'))

Endfor

 

Create Table kayitlar (kayitKod c(38) Default UniqueID(), malzemeKod c(38), diger c(30))

Index On malzemeKod Tag malzemeKod

Alter Table 'Kayitlar' Add Primary Key kayitKod Tag kayitKod

Alter Table 'Kayitlar' Add Foreign Key Tag malzemeKod References malzemeAdi Tag malzemeKod

CLOSE DATABASES all

Public oForm

oForm = Createobject('myForm')

oForm.Show()

 

Define Class myForm As Form

  DataSession = 2

  Height = 500

  Width = 600

 

  Add Object grdKayit As Grid With ;

    height=450, Width=600,Anchor=10, RowHeight = 30, RecordSource='kayitlar'

  Add Object cmdAdd As CommandButton With ;

    left=10,Top=460,Width = 75, Height=30, Caption = 'Ekle'

  Add Object cmdSave As CommandButton With ;

    left=90,Top=460,Width = 75, Height=30, Caption = 'Sakla'

  Add Object cmdRevert As CommandButton With ;

    left=170,Top=460,Width = 75, Height=30, Caption = 'Geri Al'

 

  Procedure Load

    Set Multilocks On

    Use kayitlar

    CursorSetProp("Buffering",5,'kayitlar')

  Endproc

 

  Procedure Init

    This.grdKayit.Columns(1).Enabled = .F.

    With This.grdKayit.Columns(2)

      .AddObject('cmbMalzeme','ComboBox')

      .CurrentControl = 'cmbMalzeme'

      .Sparse = .F.

      With .cmbMalzeme

        .RowSourceType = 3

        .RowSource = 'select malzemeAdi,malzemeKod from MalzemeAdi into cursor crsMalzeme'

        .Style = 2

        .ColumnCount = 2

        .BoundColumn = 2

        .ColumnWidths = "200,0"

        .Visible = .T.

      Endwith

    Endwith

  Endproc

 

  Procedure cmdAdd.Click

    Insert Into kayitlar (diger) Values ("")

    Thisform.Refresh

    Thisform.grdKayit.SetFocus

  Endproc

 

  Procedure cmdSave.Click

    Tableupdate(2,.T.,'kayitlar')

    Thisform.Refresh

  Endproc

 

  Procedure cmdRevert.Click

    Tablerevert(.T.,'kayitlar')

    Thisform.Refresh

  Endproc

Enddefine