jpeg dosyasını işleme

*ALINTI : http://blogs.msdn.com/calvin_hsia/archi … 15552.aspx
*Resize your pictures for your phone or pocket pc

PUBLIC ox as JpgForm

ox=CREATEOBJECT("JpgForm")

ox.visible=1

DEFINE CLASS JpgForm as Form

          width=640

          height=480

          left=200

          allowoutput=.f.
*RESİM BOYUTUNU BURADAN AYARLAYABİLİRSİN ÖR: 320x240
          ADD OBJECT oPict as image WITH top = 20,width=320,height=240,stretch=2

          ADD OBJECT oTrackbar as cTrackbar WITH width=300,smallchange=2

          PROCEDURE init

                   SET CLASSLIB TO HOME()+"ffc\_gdiplus"

                   SET COMPATIBLE on  && so FSIZE returns FileSize

                   this.refresh

          PROCEDURE refresh

                   this.drawit()

          PROCEDURE drawit

                   cFile="d:\kids.jpg"

                   cOutputFile="d:\thumb.jpg"

                   LOCAL oGraphics as gpGraphics OF _gdiplus.vcx

                   LOCAL oImage as gpImage OF _gdiplus.vcx

                   LOCAL oBmpOut as gpBitmap OF _gdiplus.vcx

                   oGraphics=CREATEOBJECT("gpGraphics")

                   oImage=CREATEOBJECT("gpImage",cFile)

                   oBmpOut=CREATEOBJECT("gpBitmap",this.oPict.width,this.oPict.height)

                   oGraphics.CreateFromImage(oBmpOut)

                   oGraphics.DrawImageScaled(oImage,0,0,oBmpOut.ImageWidth,oBmpOut.ImageHeight)

                   oBmpOut.SaveToFile(cOutputFile,"image/jpeg","quality="+TRANSFORM(this.oTrackbar.value))

                   this.oPict.picture=cOutputFile

                   this.Caption = TRANSFORM(this.oTrackbar.value)+" Size="+TRANSFORM(FSIZE(cOutputFile))

ENDDEFINE

DEFINE CLASS cTrackbar as olecontrol

          oleclass="mscomctllib.slider.2"

          PROCEDURE init

                   this.max=100

                   this.smallchange=2

                   this.largechange=10

          PROCEDURE change

                   thisform.drawit

ENDDEFINE