Idle time?

Public oForm

oForm = Createobject('myForm')

oForm.Show

 

Define Class myForm As Form

  DataSession=2

  Add Object myFetchStatus As Label With Caption='Fetching...', AutoSize=.T.

  Add Object myGrid As Grid With Top = 50

  Add Object myAsynchLoader As Timer With Interval = 100

 

  Procedure Load

    TEXT TO m.lcSQL noshow

SELECT *

   FROM AdventureWorks.Sales.SalesOrderHeader h

   JOIN AdventureWorks.Sales.SalesOrderDetail d ON h.SalesOrderID = d.SalesOrderID

    ENDTEXT

 

    m.lcConnection = ;

      "Driver=SQL native client;Server=.\sqlexpress;"+;

      "Trusted_connection=Yes;"

 

    This.AddProperty('oCA')

    This.oCA = Createobject("AsynchCA", "myData",m.lcSQL,m.lcConnection)

    This.oCA.CursorFill()

    Select (This.oCA.Alias)

  Endproc

 

  Procedure Init

    This.myGrid.RecordSource = Thisform.oCA.Alias

  Endproc

 

  Procedure myAsynchLoader.Timer

    This.Enabled = .F.

    With Thisform.oCA

      If CursorGetProp("FetchIsComplete", .Alias)

        Thisform.myFetchStatus.Caption = 'Fetch complete'+Ltrim(Str(Reccount(.Alias)))

        Use In 'fetchMe'

        Return

      Endif

      If !Used('fetchMe')

        Use Dbf(.Alias) In 0 Again Alias FetchMe

      Endif

      Thisform.myFetchStatus.Caption = 'Fetching...'+Ltrim(Str(Recno('fetchMe')))

      Skip (.FetchSize) In 'fetchMe'

    Endwith

    This.Enabled = .T.

  Endproc

Enddefine

 

 

Define Class AsynchCA As CursorAdapter

  DataSourceType="ODBC"

  FetchAsNeeded = .F.

  FetchSize = 1000

  MaxRecords = -1

  AllowSimultaneousFetch = .T.

 

  Procedure Init

    Lparameters tcAlias, tcSQL, tcConnection

    This.Alias = m.tcAlias

    This.AddProperty('Connection', ;

      SQLSTRINGCONNECT(m.tcConnection))

    This.Datasource = This.Connection

    This.SelectCmd = m.tcSQL

    SQLSetprop(This.Connection,"Asynchronous",.T.)

  Endproc

Enddefine