window da scroll bar?

*!*    Author : Ony Too

SET REPORTBEHAVIOR 90

 

LOCAL oRep AS FORM

oRep = CREATEOBJECT("FormReport")

 

WITH oRep AS FORM

  .Caption = "Report custom title"

  .WindowState = 2

ENDWITH

REPORT FORM LOCFILE(_Samples + "\Solution\Reports\Wrapping.frx") PREVIEW WINDOW (oRep.NAME)

 

#define SWP_NOSIZE   0x0001

#define SWP_NOMOVE   0x0002

#define HWND_TOPMOST (-1)

 

#define TB_NAME "PreviewToolbar"

 

DEFINE CLASS FormReport AS FORM

  Desktop = .T.

  nOldParent = 0

  oTB = .NULL.

 

  ADD OBJECT Timer1 AS TIMER WITH ;

    Interval=100, ;

    Enabled=.F.

 

  PROCEDURE Init

    IF this.Desktop

      DECLARE LONG GetParent IN WIN32API LONG

      DECLARE LONG SetParent IN WIN32API LONG, LONG

      DECLARE LONG SetWindowPos IN WIN32API LONG, LONG, LONG, LONG, LONG, LONG, LONG

      this.Timer1.Enabled = .T.

    ENDIF

  ENDPROC

 

  PROCEDURE Destroy

    this.Timer1.Enabled = .F.

    IF TYPE("this.oTB.Name") # "C"

      SetParent(this.oTB.HWnd, this.nOldParent)

        this.oTB = NULL

    ENDIF

  ENDPROC

 

  PROCEDURE Timer1.Timer

    this.Enabled = .F.

    IF TYPE("thisform.oTB.Name") # "C"

      LOCAL loTB

      FOR i = 1 TO _SCREEN.FormCount

        loTB = _SCREEN.Forms(i)

        IF loTB.Name == TB_NAME

          thisform.oTB = loTB

          thisform.nOldParent = GetParent(thisform.oTB.HWnd)

          SetParent(thisform.oTB.HWnd, 0)

          EXIT

        ENDIF

      ENDFOR

    ENDIF

    IF TYPE("thisform.oTB.Name") == "C"

      IF thisform.oTB.Docked

        thisform.oTB.Dock(-1)

        SetParent(thisform.oTB.HWnd, 0)

      ENDIF

      thisform.oTB.Move(0, SYSMETRIC(9))

      SetWindowPos(thisform.oTB.HWnd, HWND_TOPMOST, 0, 0, 0, 0, BITOR(SWP_NOSIZE, SWP_NOMOVE))

    ENDIF

    this.Enabled = .T.

  ENDPROC

ENDDEFINE