mail olarak gönderme

Local lcErrReturn,lcKimden,lcKime,lcFile

 

lcKimden = "soykan@soykansoft.com"

lcKime = "soykan@soykansoft.com"

m.lcFile = "d:\vfptemp\test.xls"

 

SendViaCDOSYS(@lcErrReturn, m.lcKimden, m.lcKime, "Konu", "Mesaj",m.lcFile , "cc", "bc", "mail.soykansoft.com", "soykan@soykansoft.com", "XXXXX", .t.)

 

If Empty(lcErrReturn)

    Messagebox("'" + "' Başarıyla Gönderildi", 64, "SoykanSoft - CDOSYS Mail Sending System")

Else

    Messagebox("'" + "' Gönderilemedi.  Sebebi:" + Chr(13) + lcErrReturn, 64, "SoykanSoft - CDOSYS Mail Sending System")

Endif

 

*******************************************

Function SendViaCDOSYS(tcReturn, tcFrom, tcTo, tcSubject, tcBody, taFiles, tcCC, tcBCC, tcMailServer, tcUserName, tcPassword, tlHTMLFormat)

*******************************************

 

Local lcSchema, loConfig, loMsg, loAtt, lnCountAttachments

 

Try

    lcSchema = "http://schemas.microsoft.com/cdo/configuration/"

 

    loConfig = Createobject("CDO.Configuration")

 

    With loConfig.Fields

        .Item(lcSchema + "smtpserverport") = 587 &&25 && SMTP Port

        .Item(lcSchema + "sendusing") = 2 && Send it using port

        .Item(lcSchema + "smtpserver") = tcMailServer && host of smtp server

        .Item(lcSchema + "smtpauthenticate") = 1 && Authenticate

        .Item(lcSchema + "sendusername") = tcUserName && Username

        .Item(lcSchema + "sendpassword") = tcPassword && Password

        .Update

    Endwith

 

    loMsg = Createobject ("CDO.Message")

    loMsg.Configuration = loConfig

    With loMsg

        .From = tcFrom

        .To = tcTo

        If Type("tcCC") = "C"

            .CC = tcCC

        Endif

        If Type("tcBCC") = "C"

            .BCC = tcBCC

        Endif

        .Subject = tcSubject

        If tlHTMLFormat

            .HTMLBody = tcBody

        Else

            .TextBody = tcBody

        Endif

        *!*If Type("tafiles",1) = "A"

        *!*    For lnCountAttachments = 1 To Alen(taFiles)

        *!*        loAtt=.AddAttachment(taFiles(lnCountAttachments))

        *!*    Endfor

        *!*Endif

        .AddAttachment(taFiles)

        .Send()

    Endwith

 

Catch To loError

    tcReturn = [Error: ] + Str(loError.ErrorNo) + Chr(13) + ;

        [LineNo: ] + Str(loError.Lineno) + Chr(13) + ;

        [Message: ] + loError.Message + Chr(13) + ;

        [Procedure: ] + loError.Procedure + Chr(13) + ;

        [Details: ] + loError.Details + Chr(13) + ;

        [StackLevel: ] + Str(loError.StackLevel) + Chr(13) + ;

        [LineContents: ] + loError.LineContents

Finally

    Release loConfig, loMsg

    Store .Null. To loConfig, loMsg

Endtry

EndFunc