Can't get "Append blank" to work

Public oForm

oForm = Createobject('SampleForm')

oForm.Show()

 

Define Class SampleForm As Form

  DataSession=2

  Height=600

  Width=800

  EditMode=.F.

 

  Add Object locgrdCustomer As locGrid With ;

    cSQL='* from customer',;

    Height=300, ;

    FollowTable='Customer', FollowField='cust_id',FollowTag='cust_id'

  Add Object btnNew As CommandButton With Top=310, Height=50, Width=100,Caption='New'

  Add Object btnEdit As CommandButton With Top=310, Height=50, Width=100,Left=120,Caption='Edit'

 

  Add Object cntCustomer As myCustomer With Top = 365, Left = 10, Width = 120

 

  Procedure Load

    Set Multilocks On

    Use (_samples+'data\customer')

    CursorSetProp("Buffering",5,'Customer')

  Endproc

 

  Procedure btnNew.Click

    Thisform.AddProperty('CurrentCustomerKey', Customer.Cust_id) && save current key

    If Thisform.EditMode && was adding/editing - save

      Thisform.SaveCustomer()

    Else && Insert and go in editMode

      Insert Into Customer (Cust_id) Values (Right(Sys(2015),6))

    Endif

    Thisform.EditMode = !Thisform.EditMode

  Endproc

 

  Procedure btnEdit.Click

    If Thisform.EditMode && was adding/editing - Revert

      Thisform.RevertCustomer()

    Else && go in editMode

      * Nothing here - just need to switch to editmode

    Endif

    Thisform.EditMode = !Thisform.EditMode

    Thisform.AddProperty('CurrentCustomerKey', Customer.Cust_id) && save current key

  Endproc

 

  Procedure SaveCustomer

    Local lcKey

    lcKey = Customer.Cust_id && newly inserted key

    Tableupdate(2,.T.,'Customer')

    Thisform.locgrdCustomer.Reload()

    Select (Thisform.locgrdCustomer.RecordSource)

    Locate For Cust_id = m.lcKey

 

    Thisform.locgrdCustomer.SetFocus()

    Thisform.locgrdCustomer.AfterRowColChange(1)

  Endproc

 

  Procedure RevertCustomer

    Tablerevert(.T.,'Customer')

    Select (Thisform.locgrdCustomer.RecordSource)

    Locate For Cust_id = Thisform.CurrentCustomerKey

    Thisform.locgrdCustomer.SetFocus()

    Thisform.locgrdCustomer.AfterRowColChange(1)

  Endproc

 

  Procedure EditMode_Assign(vNewVal) && insert/save

    This.EditMode = m.vNewVal

    This.cntCustomer.SetAll('Enabled', This.EditMode) && enable/disable textboxes

    This.locgrdCustomer.Enabled = !This.EditMode && enable/Disable locator grid

    This.btnNew.Caption=Iif(This.EditMode,'Save','New')

    This.btnEdit.Caption=Iif(This.EditMode,'Revert','Edit')

    Thisform.Refresh()

  Endproc

 

  Procedure Init

    This.EditMode = .F.

  Endproc

Enddefine

 

Define Class locGrid As LocatorGrid Of 'd:\FoxyClasses\Classes\grids.vcx'

Enddefine

 

Define Class myCustomer As Container

  Height=140

  Add Object txtCustID As TextBox With Top=10, Left=10,Height=30, Width=100, ;

    ControlSource='Customer.cust_id'

  Add Object txtCompany As TextBox With Top=50, Left=10,Height=30, Width=100, ;

    ControlSource='Customer.company'

  Add Object txtContact As TextBox With Top=90, Left=10,Height=30, Width=100, ;

    ControlSource='Customer.contact'

Enddefine

INSERT INTO tbtewese

INSERT INTO tbtewese () values(value1,value2,value3)

INSERT INTO tbtewese () values("Never to be seen or used")