Giriş yapmadınız. Lütfen giriş yapın yada kayıt olun.
fox4um » Microsoft Office Otomasyonu » Gönder ve al butonu
Dökümanlar sayfasındaki "outlook otomasyonu" programında herşey mükemmel olmakla beraber "Gönder ve Al" command butonu olmadığından yine outlook'a bağımlı kalınıyor. Outlook ta bildiğim kadarı ile gelen mailleri otomatik olarak almadığı için gelen mailler için outlooktan "gönder ve al" demek zorunda kalınıyor. Bu programa "Gönder ve al" butonu eklemenin bir yolu varmı?
Ustalara şimdiden teşekkürler...
Public oform1
oform1=Createobject("form1")
oform1.Show
Return
**************************************************
Define Class form1 As Form
Height = 400
Width = 620
DoCreate = .T.
Caption = "Form1"
Name = "Form1"
Add Object cmdExit As CommandButton With ;
Top = 330, ;
Left = 504, ;
Height = 27, ;
Width = 84, ;
Caption = "E<xit", ;
Name = "CmdExit"
Add Object cmdCalendar As CommandButton With ;
Top = 330, ;
Left = 12, ;
Height = 27, ;
Width = 84, ;
Caption = "<Calendar", ;
Name = "CmdCalendar"
Add Object cmdInBox As CommandButton With ;
Top = 330, ;
Left = 108, ;
Height = 27, ;
Width = 84, ;
Caption = "<In Box", ;
Name = "CmdInBox"
Add Object cmdSent As CommandButton With ;
Top = 330, ;
Left = 204, ;
Height = 27, ;
Width = 84, ;
Caption = "<Sent Mail", ;
Name = "CmdSent"
Add Object cmdContact As CommandButton With ;
Top = 330, ;
Left = 300, ;
Height = 27, ;
Width = 84, ;
Caption = "<AddressBook", ;
Name = "CmdContact"
Add Object cmdNewMail As CommandButton With ;
Top = 360, ;
Left =12 , ;
Height = 27, ;
Width = 84, ;
Caption = "New <Mail", ;
Name = "cmdNewMail"
Add Object cmdNewTask As CommandButton With ;
Top = 360, ;
Left =108 , ;
Height = 27, ;
Width = 84, ;
Caption = "New <Task", ;
Name = "cmdNewTask"
Add Object cmdNewContact As CommandButton With ;
Top = 360, ;
Left =204 , ;
Height = 27, ;
Width = 84, ;
Caption = "<New Contact", ;
Name = "cmdNewContact"
Add Object cmdNewAppointment As CommandButton With ;
Top = 360, ;
Left =300 , ;
Height = 27, ;
Width = 110, ;
Caption = "New A<ppointment", ;
Name = "cmdNewAppointment"
Add Object cmdSendandReceive As CommandButton With ;
Top = 360, ;
Left =362 , ;
Height = 27, ;
Width = 110, ;
Caption = "Send and Receive", ;
Name = "cmdSendandReceive"
Add Object olecontrol1 As OleControl With ;
Top = 12, ;
Left = 12, ;
Height = 306, ;
Width = 588, ;
Name = "Olecontrol1", ;
OleClass = "OVCtl.OVCtl.1"
Procedure cmdExit.Click
Thisform.Release()
Endproc
Procedure cmdNewMail.Click
Thisform.olecontrol1.NewMessage()
Endproc
Procedure cmdNewTask.Click
Thisform.olecontrol1.NewTask()
Endproc
Procedure cmdNewContact.Click
Thisform.olecontrol1.NewContact()
Endproc
Procedure cmdNewAppointment.Click
Thisform.olecontrol1.NewAppointment()
Endproc
Procedure cmdCalendar.Click
Thisform.olecontrol1.Folder = "CALENDAR"
Thisform.Caption = "OutLook Calendar"
Thisform.Refresh()
Endproc
Procedure cmdInBox.Click
Thisform.olecontrol1.Folder = "INBOX"
Thisform.Caption = "OutLook InBox"
Thisform.Refresh()
Endproc
Procedure cmdSent.Click
Thisform.olecontrol1.Folder = "SENT ITEMS"
Thisform.Caption = "OutLook Sent Items"
Thisform.Refresh()
Endproc
Procedure cmdContact.Click
Thisform.olecontrol1.Folder = "CONTACTS"
Thisform.Caption = "OutLook Address Book"
Thisform.Refresh()
Endproc
Procedure cmdSendandReceive.Click
Thisform.olecontrol1.SendAndReceive()
Endproc
Procedure olecontrol1.Init
This.Folder = "InBox"
Endproc
Enddefine
Sanırım bu kodu çalıştırınca istediğin olmuş olacak 
kod dökümanlar bölümündede düzenlendi...
Eline sağlık hocam.
selamlar;
Bu kodu kullanrak outlook içindeki herhangi bir e-mail veye ekli dosyasını diskte bir yere kopyalatmak mümkünmü?
Döküman arşivi için gerekli!
fox4um » Microsoft Office Otomasyonu » Gönder ve al butonu