geçersiz dosya adı karakterleri?

*!*    Author: Cetin BASOZ

 

TEXT 

1) Valid filename characters are not only letters and digits. One can use other characters like -, etc. OTOH VFP has a bug in its file finding that it can't read a file even if the file has a legal name to windows OS (I mean, under windows the filename is legal, other programs like notepad, word etc can open and read w/o any problem but VFP cannot 'see' that file. A typical example is a filename that contains a comma - some versions cannot read, you have VFP9 SP2). IMHO don't be too restrictive on user, let him go write what he wants then validate the path.

2) You want to limit file name to 8 chars but that really is not needed, OS provide the short name where appropriate. Anyway you may want to combine this with Q #1 and shorten the path. While doing that OS removes the spaces and illegal characters for you and returns a short name (8.3).

 

So combining 2 of them and utilizing VFP's putfile() capabilities (it wouldn't accept invalid filename) you could do something like this:

ENDTEXT 

 

Local lcFileName, llExists, lcShort

lcShort = ''

lcFileName = Putfile()

If !Empty(m.lcFileName)

  llExists = File(m.lcFileName)

  If !m.llExists

    Strtofile('',m.lcFileName)

  Endif

  lcShort = GetShort(m.lcFileName)

  If !m.llExists

    Erase (m.lcFileName)

  Endif

ENDIF

? m.lcShort

 

Function GetShort

  Lparameters cFileName

  Declare Integer GetShortPathName  In Win32API ;

    string @lpszLongPath,    ;

    string @lpszShortPath,    ;

    integer  cchBuffer

  Local lpszShortPath,lnPathlen

  lpszShortPath = Replicate(Chr(0),Len(m.cFileName)+20)

  lnPathlen = GetShortPathName(@m.cFileName, @m.lpszShortPath, Len(m.cFileName)+20)

  If m.lnPathlen > 0

    Return Substr(m.lpszShortPath, 1, m.lnPathlen)

  Endif

  Return ""

Endfunc