Giriş yapmadınız. Lütfen giriş yapın yada kayıt olun.
fox4um » Veritabanı, Tablo, View, Index ve SQL Syntax » Save as HTML
Merhaba
Localdeki bir table yada cursor'u html yapıp web'e yollamak istiyorum. Bunu table açıkken menüden File > save as html şeklinde kaydediyorum. Ama
1. Bunu programda kod ile nasıl yapabilirim.
2. Standart html görünümünden çıkarmak için bu koda parametre ekleyebilirmiyiz ?
Şimdiden teşekkür ederim
*!* Author : Cetin Basoz
OPEN DATABASE HOME(2)+"\Data\TestData.Dbc" SHARED
Select c.company, ;
o.order_date, o.order_id, ;
e.First_Name-(' '+e.Last_Name) As Employee, ;
oi.line_no, p.prod_name, ;
oi.unit_price, oi.quantity ;
FROM testdata!customer c ;
INNER Join testdata!orders o ON c.cust_id = o.cust_id ;
INNER Join testdata!Employee e ON o.emp_id = e.emp_id ;
INNER Join testdata!orditems oi ON o.order_id = oi.order_id ;
INNER Join testdata!products p ON oi.product_id = p.product_id ;
order By 1,2,3,5 ;
INTO CURSOR myCursor ;
nofilter
TEXT TO m.lcHeader noshow
<html>
<head>
<title>My Table</title>
<STYLE>
TH { font-family: Times, serif;
background-color: #000080;
color: #FFFFFF;
text-align: center;
font-size: X-Large;
}
.f0 { font-size: 10pt; font-family: Arial; text-align=right; }
</STYLE>
</head>
<body>
ENDTEXT
SET TEXTMERGE TO memvar m.lcHeader ADDITIVE noshow
SET TEXTMERGE on
\<table border='1' cellspacing=0>
\ <tr>
FOR ix=1 TO FCOUNT()
\ <th><<PROPER(FIELD(m.ix))>></th>
ENDFOR
\ <tr>
SCAN
\ <tr>
FOR ix=1 TO FCOUNT()
DO CASE
CASE TYPE(FIELD(m.ix)) = 'Y'
\ <td class='f0'>
\\<<TRANSFORM(EVALUATE(FIELD(m.ix)),'@R $$9,999,999')>>
CASE TYPE(FIELD(m.ix)) = 'N'
\ <td class='f0'>
\\<<TRANSFORM(EVALUATE(FIELD(m.ix)),'@R 99,999,999')>>
otherwise
\ <td>
\\<<EVALUATE(FIELD(m.ix))>>
endcase
\ </td>
ENDFOR
\ <tr>
endscan
\</table>
\</body>
\</html>
SET TEXTMERGE to
SET TEXTMERGE off
STRTOFILE(m.lcHeader,"C:\HtmlTest.Html")
* _Cliptext = m.lcHeader
Gökçe abi, Web e yollamak için FTP örneğide gerekiyor mu?
Örnek kod için teşekkür ederim. İşim görüldü. Html dosyasını ftp ile vfp altından sorunsuz olarak host'a yolluyorum. Ama ne yazıkki otomasyon burada bitiyor. Joomla kullandığım için bu html kodunu bir "makale" içine kopyala - yapıştır yapmam gerekiyor. Aksi yaktirde bu sayfa browserde bağımsız bir sayfa olarak açılıyor ve sayfanın ana teması haricinde bir görüntü oluşuyor. Joomla küçük ve orta büyüklükteli siteler için tek kelimeyle harika. Ancak böyle ufak tefek kusurlarıda var.
Joomla nın özellilklerini pek bilmiyorum ama MySQL Kullandığı için; istediğin dosyayı istediğin biçimde MySQL e ekleyebilmen gerekiyor. Kolay bir yolu olmalı ...
Doğru. Dataları MySQL'e yazabiliriz. Ancak sonuçta web ayağında Joomla için bu dataları alıp ekrana yazacak başka bir modül daha yazmak gerekir. Projenin henüz alfa aşamasında olduğumuız için bunu daha ilerki aşamalarda düşüneceğiz.
Gökçe abi, şimdiden kolay gelsin ... İstediğin gibi bir proje olur inşallah..
fox4um » Veritabanı, Tablo, View, Index ve SQL Syntax » Save as HTML