Ekran Çözünürlüğü nü VFP den değiştirmek...

*SetScreenresolution.prg

Lparameters tnWidth,tnHeight,tnFrequency

 

#Define ENUM_CURRENT_SETTINGS -1

#Define CDS_UPDATEREGISTRY = 0x01

#Define CDS_TEST 0x02

#Define DISP_CHANGE_SUCCESSFUL 0

#Define DISP_CHANGE_RESTART 1

#Define DISP_CHANGE_FAILED -1

#Define DM_PELSWIDTH 0x00080000

#Define DM_PELSHEIGHT 0x00100000

#Define DM_DISPLAYFREQUENCY 0x00400000

 

Local lpDevMode,result

Declare Integer EnumDisplaySettings In win32API ;

    string deviceName,;

    integer modeNum, ;

    string @ lpdevMode

 

Declare Long ChangeDisplaySettings In win32API ;

    string lpDevMode, ;

    integer dwflags

 

lpdevMode = Replicate(Chr(0),512)

 

EnumDisplaySettings(0,ENUM_CURRENT_SETTINGS,@lpdevMode)

 

*!*    ? "Current settings are:",;

*!*        CTOBIN(Substr(m.lpdevMode,109,4),"4RS"),;

*!*        CTOBIN(Substr(m.lpdevMode,113,4),"4RS")

 

* Width and Height

lpdevMode = Stuff(m.lpdevMode,109,4,Int2DWord(m.tnWidth))

lpdevMode = Stuff(m.lpdevMode,113,4,Int2DWord(m.tnHeight))

 

If !Empty(m.tnFrequency)

    lpdevMode = Stuff(m.lpdevMode,121,4,Int2DWord(m.tnFrequency)) && Frequency

    lpdevMode = Stuff(m.lpdevMode,41,4,;

        Int2DWord(Bitor(DM_PELSWIDTH,DM_PELSHEIGHT,DM_DISPLAYFREQUENCY))) && dmFields

Else

    lpdevMode = Stuff(m.lpdevMode,41,4,;

        Int2DWord(Bitor(DM_PELSWIDTH,DM_PELSHEIGHT))) && dmFields

Endif

 

result = ChangeDisplaySettings(m.lpdevMode,CDS_TEST)

 

If !( result = DISP_CHANGE_SUCCESSFUL )

    Messagebox("Mode is not supported",0+48,'Monitor settings')

Else

    ChangeDisplaySettings(m.lpdevMode,0)

TEXT to m.lcSetting noshow

Your screen resolution has been changed.

Press [Yes] to keep.

 

Will automatically restore your resolution in 30 seconds.

ENDTEXT

    If Messagebox(m.lcSetting,4+64,'Monitor settings',30000) != 6

        ChangeDisplaySettings(0,0) && restore

    Endif

Endif

 

Function Int2DWord(tInt)

    Local lcDWord,ix

    lcDWord = ''

    For ix=1 To 4

        lcDword = m.lcDword + Chr( Int(m.tInt/256^(m.ix-1)) % 256 )

    Endfor

    Return m.lcDword

Endfunc