Giriş yapmadınız. Lütfen giriş yapın yada kayıt olun.
fox4um » Kodlama ve Komutlar » Gridi Renklendirme
Griddeki kolonları renklendirmek için mygrid.setall(".... komutunu kullanarak backcolor veya forecolor larını renklendirebiliyorm. Griddeki column?.text1.forecolor' ları 0, sıfırdan küçük ve sıfırdan büyük şeklinde 3 tercihli nasıl belirtebilirim. Örnek: Griddeki text1 lerdeki tüm 0 lar mavi, sıfırdan kücük olanlar kırmızı, 0 dan büyük ise yeşil gibi.
column 'un DynamicBackColor ını aşağıdaki gibi düznlersen koşula göre renklenir.
aynı işlemi yazı rengi içinde uygulayabilirsin. DynamicForeColor ..
iif(seplist.sd="1",rgb(255,0,0),rgb(255,255,255))
DynamicBackColor'ı iki kez kullanabilirsiniz.
VFP9 kullaniyorsan icase() kullanabilirsin. Yoksa icice iif():
thisform.myGrid.SetAll( "DynamicBackColor", ;
"(icase( alias.Field < 0, 0xFF, alias.Field > 0, 0x00FF00, 0xFF0000))" )
thisform.myGrid.SetAll( "DynamicBackColor", ;
"(iif( alias.Field < 0, 0xFF, iif(alias.Field > 0, 0x00FF00, 0xFF0000)))" )
Bu iş kolay görünüyor, ancak senin şartın karmaşıklaştıkça bu icase(), iif() vs yazmak zorlaşıyor ve hata yapma şansı artıyor. Hatalı yazdıysan, VFP hata mesajı vermez ama renklendirmeyi de yapmaz.
O nedenle karmaşık ifadeleri oraya yazmak yerine, oraya cok basit bir ifade yazabilirsin:
thisform.myGrid.SetAll( "DynamicBackColor", "(thisform.GridArkaRenk())" )
İhtiyacına gore o metoda parametre de gonderebilirsin ve SetAll'un cozemedigi durumlarda daha esnek kullanabilirsin.
Parametreli ve SetAll'un cevap olmadıgı durumlar icin ornek:
Public oForm
oForm = Createobject("myForm")
oForm.Show()
Define Class myForm As Form
DataSession = 2
Height = 600
Width = 800
Add Object grid1 As Grid With ;
left=0,Width = 400,Height=600,RecordSource="ornekData"
Add Object grid2 As Grid With ;
left=400,Width = 400,Height=600,RecordSource="ornekData"
Procedure Load
Rand(-1)
Select ;
Int(Rand()*20) - 10 As sayi, ;
Company, ;
Country, ;
DATE(2006, Int(Rand()*11)+1, 1) As tarih ;
FROM (_samples+'data\customer') ;
INTO Cursor ornekData ;
nofilter
Endproc
Procedure grid1.Init
This.Columns(1).Width = 30
This.Columns(2).Width = 200
This.Columns(3).Width = 60
This.Columns(4).Width = 60
This.SetAll("DynamicBackColor", "(thisform.GridArkaRenkOrnek1( ornekData.Sayi ))")
Endproc
Procedure grid2.Init
This.Columns(1).Width = 30
This.Columns(2).Width = 200
This.Columns(3).Width = 60
This.Columns(4).Width = 60
Local ix
For ix = 1 To This.ColumnCount
With This.Columns(m.ix)
.DynamicBackColor = ;
"(thisform.GridArkaRenkOrnek2('" + .ControlSource +"'))"
Endwith
Endfor
Endproc
Procedure GridArkaRenkOrnek1(tnSayi)
Do Case
Case m.tnSayi > 0
Return 0x00FF00
Case m.tnSayi < 0
Return 0xFF
Otherwise
Return 0xFF0000
Endcase
Endproc
Procedure GridArkaRenkOrnek2(tcControlSource)
Local lcType, luValue
lcType = Type(m.tcControlSource)
If m.lcType != "G"
luValue = Evaluate(m.tcControlSource)
Endif
Do Case
Case m.lcType = "C"
* Degerin crc degerine gore renk
Return BITLSHIFT(VAL(SYS(2007,m.luValue)),8)
Case m.lcType = "D"
* 3 aylik donemlere gore renk
Do Case
Case Ceiling(Month(m.luValue)/3) = 1
Return 0xFFFF00
Case Ceiling(Month(m.luValue)/3) = 2
Return 0xFF00FF
Case Ceiling(Month(m.luValue)/3) = 3
Return 0x00FFFF
Otherwise
Return 0xC0C0C0
Endcase
Case m.lcType = "N"
Do Case
Case m.luValue > 0
Return 0x00FF00
Case m.luValue < 0
Return 0xFF
Otherwise
Return 0xFF0000
Endcase
Endcase
Return 0xFFFFFF
Endproc
Enddefine
Çetin bey teşekkür ederim. örnek2 procedurunu uygulayınca istediğim sonucu aldım.
merhabalar,
klpkod makina
klp001 mk01
klp001 mk02
klp003 mk01
klp004 mk08
klp004 mk01
şeklinde bir tableda klpkod değiştiğinde satır renginide nasıl değiştirebilirim
çetin bey link olarak bu sayfayı vermişsiniz, defalarca bakmıştım bu sayfaya ve birtürlü yapamadım,o yüzden yine bu sayfaya yazdım 
gride bağladığın cursora bir field daha aç (.t., .f. girilecek):
örneğin gridcursoru( klpkod C(10), makina C(10) ,değişti L)
klpkod u bağladığın myform.mygrid.Column1.Text1.InteractiveChange evente:
REPL gridcursoru.değişti WITH .t. IN gridcursoru
myform.mygrid.SetALL;
("DynamicForeColor","IIF(gridcursoru.değişti,RGB(100,200,200),RGB(200,200,100))","Column")
Public oform
oform=Newobject("myForm")
oform.Show
Return
Define Class myForm As Form
DataSession = 2
Top = 0
Left = 0
Height = 300
Width = 500
Add Object grdcustomer As Grid With ;
Height = 280, Left = 10, ;
RecordSource = "select * from (_samples+'data\customer') order by country into cursor crsByCountry", ;
RecordSourceType = 4, ;
Top = 10, Width = 480
Procedure Init
With This.grdcustomer
.AddProperty('cCurCountry','')
.SetAll("DynamicBackColor", ;
"IIF(crsByCountry.Country=this.cCurCountry,0xC0C0C0,0xFFFFFF)")
Endwith
Endproc
Procedure grdcustomer.BeforeRowColChange
Lparameters nColIndex
Thisform.LockScreen = .T.
Endproc
Procedure grdcustomer.AfterRowColChange
Lparameters nColIndex
This.cCurCountry = crsByCountry.Country
Thisform.LockScreen = .F.
Endproc
Enddefine
çetin bey istediğimden çokdaha güzel bir çözüm sundunuz çok teşekkür ederim.
bu örneği locator gridde kullanmak istedim ama olmadı, gerçi locatorgridde kullanmak nekadar mantıklı bilmiyorum ama en azından denemek isterim.
form inite
SET NULLDISPLAY TO ""
WITH ThisForm.locatorgrid1
.csql = " A.klpkod,A.tanim,A.klpgoz,b.TEZGAH,B.SIRA "+;
"from klp_kart A left join KLP_TEZ B on A.klpkod = B.klpkod order by B.klpkod"
.init()
.Width = 800
.Height = 500
.columncount = 5
.column1.width = 80
.....
.column5.width = 100
.addproperty('cklpkod','')
.SetAll("DynamicBackColor", ;
"IIF(this.recordsource+'.klpkod')=this.cklpkod,0xC0C0C0,0xFFFFFF)")
ENDWITH
locatorgrid1.afterrowcolchange
lparameters nColIndex
This.cklpkod = (this.recordsource+'.klpkod')
Thisform.LockScreen = .F.
beforerowcolchange e ise
LPARAMETERS nColIndex
Thisform.LockScreen = .T.
yazdım
Ah locatorgridde isler oyle degil, Onun zaten kullandigi dynamicbackcolor yani sira before/afterrowcolchange event kodu var.
Public oform
oform=Newobject("myForm")
oform.Show
Return
Define Class myForm As Form
DataSession = 2
Top = 0
Left = 0
Height = 300
Width = 500
Add Object grdcustomer As locGrid With ;
Height = 280, Left = 10, ;
Top = 10, Width = 480
Procedure Init
With This.grdcustomer
.cSQL = "* from (_samples+'data\customer') order by country"
.Init()
.AddProperty('cCurCountry','')
* BackColor
.SetAll("DynamicBackColor", ;
"IIF("+ .RecordSource + ".Country=this.cCurCountry,0xA0FFFF,0xFFFFFF)")
* Secili kaydin fontu bold ve arka alan rengiyle uyumlu 'sari-lacivert renklerimiz...';)
.SetAll("DynamicFontBold", "RecNo(This.RecordSource) = This.nCurRec")
.SetAll("DynamicForeColor", "(IIF(RecNo(This.RecordSource) = This.nCurRec, 0xFF2020,0))")
Endwith
Endproc
Procedure grdcustomer.AfterRowColChange
Lparameters nIndex
This.cCurCountry = Evaluate(This.RecordSource+'.Country')
DoDefault(m.nIndex)
Endproc
Enddefine
Define Class locGrid As locatorgrid Of 'd:\foxyclasses\classes\grids.vcx'
Enddefine
Not: Renkleri degistirirsen ben gormeyeyim:)
çetin bey ellerinize sağlık tadından yenmiyo valla
çok teşekkür ederim
Not : renkleri değiştirmedim aslına sadık kaldım
Bu güzel örnekler den olayı tekrar foxpro dostlarına teşekkür ederim.İhtiyaç oldu,ilaç gibi geldi valla.. eksik olmayınız 
Üstat gerçekten çok güzel örnek.
Ellerine sağlık
print için şunu yazdım
SELECT tanim,oneri,birim,miktar ,kod ,termin FROM crsmrpt2 WHERE oneri>0 INTO CURSOR crsmrptui ORDER BY kod,termin
REPORT FORM "E:\PLANPRES\emir\raporlar\IHTURUN.frx" TO PRINTER PROMPT PREVIEW
print butonuna bastıktan sonra form ekranına döndüğünde form ekranı beyaz oluyor formun içinde herhangi biryere tıkladığında yine normale dönüyor.bunu nasıl düzeltebilirim
Visual Fox ProPublic oform
oform=Newobject("myForm")
oform.Show
Return
Define Class myForm As Form
DataSession = 2
Top = 0
Left = 0
Height = 300
Width = 500
Add Object grdcustomer As Grid With ;
Height = 280, Left = 10, ;
RecordSource = "select * from (_samples+'data\customer') order by country into cursor crsByCountry", ;
RecordSourceType = 4, ;
Top = 10, Width = 480
Procedure Init
With This.grdcustomer
.AddProperty('cCurCountry','')
.SetAll("DynamicBackColor", ;
"IIF(crsByCountry.Country=this.cCurCountry,0xC0C0C0,0xFFFFFF)")
Endwith
Endproc
Procedure grdcustomer.BeforeRowColChange
Lparameters nColIndex
Thisform.LockScreen = .T.
Endproc
Procedure grdcustomer.AfterRowColChange
Lparameters nColIndex
This.cCurCountry = crsByCountry.Country
Thisform.LockScreen = .F.
Endproc
Enddefine
Raporu çalıştırmadan önce :
ThisForm.LockScreen = .T.
Rapordan sonra
ThisForm.LockScreen = .F.
uğur yardımın için çok teşekkür ederim
fox4um » Kodlama ve Komutlar » Gridi Renklendirme